Задание 9. Работа с электронными таблицами. ЕГЭ 2026 по информатике
Средний процент выполнения: 32%
Ответом к заданию 9 по информатике может быть цифра (число) или слово.
Алгоритм решения задания 9:
- Внимательно прочитай условие и пойми, что нужно найти (значение в ячейке, результат формулы, диапазон, условие).
- Определи, какие исходные данные даны в таблице и в каких ячейках они находятся.
- Разбери формулу(ы), которые используются: ссылки на ячейки, операции, функции.
- Вычисляй выражение по порядку: сначала действия в скобках, затем функции, затем остальные операции.
- Если есть копирование формулы, учти изменение ссылок (относительные/абсолютные).
- При необходимости вычисли значения промежуточных ячеек, от которых зависит ответ.
- Проверь, что расчёт соответствует условию (правильные диапазоны, условия и единицы).
- Запиши ответ в требуемом формате.
Подпишись на суперполезные материалы
Задачи для практики
Задача 1
Откройте файл электронной таблицы, содержащей в каждой строке шесть натуральных чисел. Определите количество строк таблицы, содержащих числа, для которых выполнены оба условия:
– в строке только одно число повторяется трижды, остальные числа различны;
– квадрат суммы всех повторяющихся чисел строки больше квадрата суммы всех её неповторяющихся чисел.
В ответе запишите только число.
Решение
f = open('9_24.txt').readlines()
c = 0
for line in f:
a = list(map(int, line.split()))
povt = []
nepovt = []
for i in a:
if a.count(i) == 3:
povt.append(i)
if a.count(i) == 1:
nepovt.append(i)
if len(nepovt) == 3 and len(povt) == 3:
if sum(povt)**2 > sum(nepovt)**2:
c += 1
print(c)
Задача 2
Откройте файл электронной таблицы, содержащей в каждой строке четыре натуральных числа. Определите количество строк таблицы, в которых сумма наибольшего и наименьшего чисел меньше суммы двух оставшихся.
Решение
f = open('9.txt').readlines()
c = 0
for line in f:
a = sorted(map(int, line.split()))
if sum(a[1:-1]) > a[0] + a[-1]:
c += 1
print(c)
Задача 3
Откройте файл электронной таблицы, содержащей в каждой строке шесть натуральных чисел. Определите, сколько существует строк, в которых выполняются сразу два условия:
1) в строке ровно одно число повторяется три раза, а остальные различны
2) сумма повторяющихся чисел не меньше суммы неповторяющихся чисел
Решение
Создадим в начале пустую строку и запишем в неё числа от 1 до 6 для упрощения функции "НАИМЕНЬШИЙ".
В ячейке G2 запишем и растянем в диапазоне G2:L2 формулу =НАИМЕНЬШИЙ(\$A2:\$F2;G\$1)
В ячейке М2 запишем и растянем в диапазоне M2:P2 формулу =ЕСЛИ(И(G2=H2;G2=I2);1;0), определяющий, равны ли 3 числа между собой.
В ячейке Q2 посчитаем количество троек, в которых все числа равны с помощью формулы =СУММ(M2:P2)
Выделим повторяющийся элемент с помощью формулы в ячейке R2: =G2*M2+H2*N2+I2*O2+J2*P2
В ячейке S2 пишем итоговую формулу и вычисляем количество =ЕСЛИ(И(СУММ(G2:L2)<=6*R2;Q2=1);1;0). Общее количество единиц: 6.
Задача 4
Откройте файл электронной таблицы, содержащей в каждой строке шесть натуральных чисел. Определите, сколько существует строк, в которых выполняются сразу два условия:
1) в строке ровно одно число повторяется три раза, а остальные различны
2) сумма повторяющихся чисел не меньше суммы неповторяющихся чисел
Решение
Создадим в начале пустую строку и запишем в неё числа от 1 до 6 для упрощения функции "НАИМЕНЬШИЙ".
В ячейке G2 запишем и растянем в диапазоне G2:L2 формулу =НАИМЕНЬШИЙ(\$A2:\$F2;G$1)
В ячейке М2 запишем и растянем в диапазоне M2:P2 формулу =ЕСЛИ(И(G2=H2;G2=I2);1;0), определяющий, равны ли 3 числа между собой.
В ячейке Q2 посчитаем количество троек, в которых все числа равны с помощью формулы =СУММ(M2:P2)
Выделим повторяющийся элемент с помощью формулы в ячейке R2: =G2*M2+H2*N2+I2*O2+J2*P2
В ячейке S2 пишем итоговую формулу и вычисляем количество =ЕСЛИ(И(СУММ(G2:L2)<=6*R2;Q2=1);1;0). Общее количество единиц: 1.
Задача 5
Откройте файл электронной таблицы, содержащей в каждой строке шесть натуральных чисел. Определите, сколько существует строк, в которых выполняются сразу два условия:
1) в строке все числа уникальны, ни одно не повторяется
2) среднее арифметическое максимального и минимального числа больше среднего арифметического всех чисел.
Решение
В ячейки G1:L1 запишем числа от 1 до 6 для определения порядкового номера "максимальности".
В ячейки G2:L2 запишем формулу =НАИМЕНЬШИЙ(\$A2:\$F2;G\$1), чтобы расположить числа в порядке возрастания.
Далее будем попарно сравнивать значения, записав и перетянув в ячейки M2:Q2 формулу =ЕСЛИ(G2=H2;1;0), а затем узнаем, есть ли уникальные с помощью формулы в ячейке R2: =ИЛИ(M2;N2;O2;P2;Q2)
Для строк, в которых результат ЛОЖЬ, проверяем второе условие в ячейке S1: =ЕСЛИ(R2=ЛОЖЬ; ЕСЛИ((G2+L2)/2>СРЗНАЧ(G2:L2);1;0);0)
Посчитаем итоговое количество единиц в столбце S, это будет окончательным ответом: 424.
Задача 6
Откройте файл электронной таблицы, содержащей в каждой строке шесть натуральных чисел. Определите количество строк таблицы, содержащих числа, для которых выполнены все условия:
– в строке есть уникальное число;
– в строке есть число, которое повторяется два раза;
– в строке есть число, которое повторяется три раза;
–сумма трёх одинаковых чисел строки не больше суммы оставшихся чисел.
В ответе запишите только число.
Решение
В строке G1 нужно записать формулу =СЧЁТЕСЛИ(\$A1:\$F1;A1), далее скопировать ей в ячейки с H1 до L1, после чего растянуть вниз.
В ячейке М1 нужно записать формулу =СУММ(G1:L1)=14, а в ячейке N1 =СУММЕСЛИ(G1:L1;3;A1:F1)<=СУММЕСЛИ(G1:L1;2;A1:F1)+СУММЕСЛИ(G1:L1;1;A1:F1)
В ячейку O1 запишем финальную формулу: =СЧЁТЕСЛИМН(M1:M16000;"ИСТИНА";N1:N16000;"ИСТИНА")
Задача 7
Откройте файл электронной таблицы, содержащей в каждой строке шесть натуральных чисел. Определите, сколько существует строк, в которых выполняются сразу два условия:
1) в строке все числа уникальны, ни одно не повторяется
2) среднее арифметическое максимального и минимального числа больше среднего арифметического всех чисел.
Решение
В ячейки G1:L1 запишем числа от 1 до 6 для определения порядкового номера "максимальности".
В ячейки G2:L2 запишем формулу =НАИМЕНЬШИЙ(\$A2:\$F2;G\$1), чтобы расположить числа в порядке возрастания.
Далее будем попарно сравнивать значения, записав и перетянув в ячейки M2:Q2 формулу =ЕСЛИ(G2=H2;1;0), а затем узнаем, есть ли уникальные с помощью формулы в ячейке R2: =ИЛИ(M2;N2;O2;P2;Q2)
Для строк, в которых результат ЛОЖЬ, проверяем второе условие в ячейке S1: =ЕСЛИ(R2=ЛОЖЬ; ЕСЛИ((G2+L2)/2>СРЗНАЧ(G2:L2);1;0);0)
Посчитаем итоговое количество единиц в столбце S, это будет окончательным ответом: 431.
Задача 8
Откройте файл электронной таблицы, содержащей в каждой строке четыре натуральных числа, координаты двух точек, начала и конца отрезка: x1, y1, x2, y2. Найдите сумму длин отрезков меньших 10. При решении воспользоваться формулой вычисления длины отрезка по двум точкам. В ответе запишите только целую часть числа.
Решение
Длина отрезка вычисляется по формуле: =КОРЕНЬ((A1-C1)^2+(B1-D1)^2)
Найдём суммы длин отрезков =СУММЕСЛИ(E:E;"<10")
В ответе запишем только целую часть.
Задача 9
Откройте файл электронной таблицы, содержащей в первой строке координаты центра и радиус окружности (x, y, R), в каждой последующей строке два целых числа, координаты точки: x1, y1. Найдите сколько точек лежит внутри круга с центром в точке x, y и радиуса R. При решении можно воспользоваться уравнением окружности. В ответе запишите только одно число.
Решение
В общем виде уравнение окружности выглядит следующим образом: (x – a)2 + (y – b)2 = R2, где a и b – координаты центра окружности.
Для начала нужно проверить, лежит точка внутри окружности или нет, если точка находится внутри окружности, то поставить 1, иначе 0: =ЕСЛИ((A2-\$A\$1)^2+(B2-\$B\$1)^2<\$C\$1^2;1;0)
Обратите внимание на то, что некоторые ссылки являются абсолютными, т.к. уравнение окружности применимо только для первой строки из таблицы.
Посчитать количество точек, которые расположены внутри окружности можно по формуле: =СУММ(D:D)
В ответе запишем полученный результат.
Задача 10
Откройте файл электронной таблицы, содержащей в каждой строке шесть целых чисел (координаты трёх точек: x1, y1, x2, y2, x3, y3). Определит сколько существует треугольников с периметром больше 1000 и меньше 2000. При решении воспользоваться формулой вычисления расстояния между двумя точка. В ответе запишите только одно число - количество треугольников, удовлетворяющих условию.
Решение
Для вычисления периметра нам необходимо найти длины сторон треугольника. Для этого вычислим все 3 расстояния между точками.
Для вычисления расстояния воспользуемся формулой: =КОРЕНЬ((E1-C1)^2+(F1-D1)^2)
И напишем ещё две аналогичные формулы для вычисления расстояний между остальными точками.
=КОРЕНЬ((C1-A1)^2+(D1-B1)^2)
=КОРЕНЬ((E1-A1)^2+(F1-B1)^2)
После этого найдём сумму длин всех сторон: =СУММ(G1:I1)
Посчитаем сколько значений удовлетворяет условию: =СЧЁТЕСЛИМН(J:J;">1000";J:J;"<2000")
Задача 11
Откройте файл электронной таблицы, содержащей в каждой строке четыре натуральных числа. Определите количество строк, в которых числа расположены в порядке возрастания: каждое следующее число больше или равно предыдущего. В ответе запишите только число.
Решение
Воспользуемся функцией ЕСЛИ, в которой объединим несколько условий через функцию И: =ЕСЛИ(И(A1<=B1;B1<=C1;C1<=D1);1;0)
Посчитаем количество единиц в финальном столбце: 35.
Ответ: 35.
Задача 12
Откройте файл электронной таблицы, содержащей в каждой строке четыре натуральных числа. Определите количество строк, в которых числа расположены в порядке убывания: каждое следующее число меньше или равно предыдущего. В ответе запишите только число.
Решение
Воспользуемся функцией ЕСЛИ, в которой объединим несколько условий через функцию И: =ЕСЛИ(И(A1>=B1;B1>=C1;C1>=D1);1;0)
Посчитаем количество единиц в финальном столбце: 39.
Ответ: 39.
Задача 13
Откройте файл электронной таблицы, содержащей в каждой строке три натуральных числа. Назовём тройку "подходящей", если в ней самое большее число равно удвоенному среднему (по величине) или удвоенному меньшему: a = 2b ИЛИ a = 2c. Посчитайте количество "подходящих" троек. В ответе запишите только число.
Решение
Чтобы определить наибольшее из чисел, воспользуемся формулой в ячейке E1: =МАКС(A1:C1)
Чтобы определить наименьшее из чисел, воспользуемся формулой в ячейке F1: =МИН(A1:C1)
Чтобы определить среднее число, воспользуемся формулой в ячейке G1: =СУММ(A1:C1)-МАКС(A1:C1)-МИН(A1:C1)
Формулу из условия проверим функцией: =ЕСЛИ(ИЛИ(E1=2*F1;E1=2*G1);1;0)
Посчитаем количество строк, принимающих единицу в финальном столбце столбцах. Их 19.
Ответ: 19.
Задача 14
Откройте файл электронной таблицы, содержащей в каждой строке три натуральных числа. Назовём тройку "подходящей", если в ней самое большее число равно сумме удвоенного среднего (по величине) числа и утроенного меньшего числа: a = 2b+3c. Посчитайте количество "подходящих" троек. В ответе запишите только число.
Решение
Чтобы определить наибольшее из чисел, воспользуемся формулой в ячейке E1: =МАКС(A1:C1)
Чтобы определить наименьшее из чисел, воспользуемся формулой в ячейке F1: =МИН(A1:C1)
Чтобы определить среднее число, воспользуемся формулой в ячейке G1: =СУММ(A1:C1)-МАКС(A1:C1)-МИН(A1:C1)
Формулу из условия проверим функцией: =ЕСЛИ(E1=2*G1+3*F1;1;0)
Посчитаем количество строк, принимающих единицу в финальном столбце столбцах. Такая только одна.
Ответ: 1.
Задача 15
Откройте файл электронной таблицы, содержащей в каждой строке три натуральных числа (длины трёх отрезков). Определит сколько существует треугольников с площадью больше 1000 и меньше 2000, который можно составить из этих троек чисел. При решении воспользоваться неравенством треугольника и формулой Герона. В ответе запишите только одно число - количество треугольников, удовлетворяющих условию.
Решение
Согласно неравенству треугольника, в любом треугольнике сумма длин двух сторон всегда должна быть больше третьей. Чтобы проверить неравенство треугольника, достаточно убедиться, что сумма длин двух наименьших сторон больше длины наибольшей стороны. Площадь треугольника будем находить по формуле Герона.
Чтобы определить наибольший из отрезков, воспользуемся формулой в ячейке D1: =МАКС(A1:C1)
Чтобы определить наименьший из отрезков, воспользуемся формулой в ячейке E1: =МИН(A1:C1)
Чтобы определить средний отрезок, воспользуемся формулой в ячейке F1: =МЕДИАНА(A1:C1)
Чтобы определить полупериметр, воспользуемся формулой в ячейке H1: =СУММ(A1:C1)/2
Неравенство треугольника проверим формулой =ЕСЛИ(D1<E1+F1;1;0)
Добавим в эту формулу вместо единицы формулу Герона и запишем в ячейку G1: =ЕСЛИ(D1<E1+F1;КОРЕНЬ(H1*(H1-D1)*(H1-E1)*(H1-F1));0)
Найдём количество площадей, удовлетворяющих условию: =СЧЁТЕСЛИМН(G:G;">1000";G:G;"<2000")
Ответ: 1266.
Задача 16
Откройте файл электронной таблицы, содержащей в каждой строке шесть натуральных чисел, координаты и радиус двух окружностей: x1, y1, r1, x2, y2, r2. Определите количество строк, в которых эти две окружности касаются, пересекаются или одна окружность находится внутри другой. В ответе запишите только число.
Решение
В данном случае достаточно проверить, что расстояние между окружностями меньше или равно сумме их радиусов.
Воспользуемся формулой: =ЕСЛИ(КОРЕНЬ((D1-A1)^2+(E1-B1)^2)<=C1+F1;1;0)
Посчитать количество окружностей, удовлетворяющих условию: =СУММ(H:H)
В ответе запишем полученный результат.
Задача 17
Откройте файл электронной таблицы, содержащей в каждой строке шесть натуральных чисел, координаты и радиус двух окружностей: x1, y1, r1, x2, y2, r2. Определите количество строк, в которых одна окружность находится внутри другой. В ответе запишите только число.
Решение
В данном случае достаточно проверить, что расстояние между центрами окружностей меньше разности их радиусов по модулю.
Воспользуемся формулой: =ЕСЛИ(КОРЕНЬ((D1-A1)^2+(E1-B1)^2)<=ABS(C1-F1);1;0)
Посчитать количество окружностей, удовлетворяющих условию: =СУММ(H:H)
В ответе запишем полученный результат.
Задача 18
Откройте файл электронной таблицы, содержащей в каждой строке три натуральных числа. Определите количество троек чисел, из которых возможно составить треугольник согласно неравенству треугольника. В ответе запишите только число.
Решение
Согласно неравенству треугольника, в любом треугольнике сумма длин двух сторон всегда должна быть больше третьей. Чтобы проверить неравенство треугольника, достаточно убедиться, что сумма длин двух наименьших сторон больше длины наибольшей стороны.
Чтобы определить наибольший из отрезков, воспользуемся формулой в ячейке E1: =МАКС(A1:C1)
Чтобы определить наименьший из отрезков, воспользуемся формулой в ячейке F1: =МИН(A1:C1)
Чтобы определить средний отрезок, воспользуемся формулой в ячейке G1: =СУММ(A1:C1)-МАКС(A1:C1)-МИН(A1:C1)
Неравенство треугольника проверим формулой =ЕСЛИ(E1<F1+G1;1;0)
Посчитаем количество единиц в финальном столбце, получим 528 подходящих троек.
Ответ: 528.
Задача 19
Откройте файл электронной таблицы, содержащей в каждой строке три натуральных числа (длины трёх отрезков). Определит сколько существует треугольников с тупым углом. При решении данной задачи воспользуйтесь теоремой Пифагора. В ответе запишите только одно число - количество треугольников, удовлетворяющих условию.
Решение
Согласно неравенству треугольника, в любом треугольнике сумма длин двух сторон всегда должна быть больше третьей. Чтобы проверить неравенство треугольника, достаточно убедиться, что сумма длин двух наименьших сторон больше длины наибольшей стороны. В треугольнике один из углов будет тупым, если квадрат самой длинной стороны больше суммы квадратов двух других сторон.
Чтобы определить наибольший из отрезков, воспользуемся формулой в ячейке D1: =МАКС(A1:C1)
Чтобы определить наименьший из отрезков, воспользуемся формулой в ячейке E1: =МИН(A1:C1)
Чтобы определить средний отрезок, воспользуемся формулой в ячейке F1: =МЕДИАНА(A1:C1)
Неравенство треугольника проверим формулой =ЕСЛИ(D1<E1+F1;1;0)
Добавим в эту формулу вместо единицы формулу для проверки угла и запишем в ячейку G1: =ЕСЛИ(D1<(E1+F1);ЕСЛИ(D1^2>(E1^2+F1^2);1;0);0)
Найдём количество треугольников, удовлетворяющих условию: =СУММ(G1:G7500)
Ответ: 2060.
Задача 20
Откройте файл электронной таблицы, содержащей в каждой строке три натуральных числа. Определите максимальную площадь треугольника, который можно составить из троек чисел. При решении воспользоваться неравенством треугольника и формулой Герона. В ответе запишите только одно число - значение максимальной площади, округлённое до целого.
Решение
Согласно неравенству треугольника, в любом треугольнике сумма длин двух сторон всегда должна быть больше третьей. Чтобы проверить неравенство треугольника, достаточно убедиться, что сумма длин двух наименьших сторон больше длины наибольшей стороны. Площадь треугольника будем находить по формуле Герона.
Чтобы определить наибольший из отрезков, воспользуемся формулой в ячейке E1: =МАКС(A1:C1)
Чтобы определить наименьший из отрезков, воспользуемся формулой в ячейке F1: =МИН(A1:C1)
Чтобы определить средний отрезок, воспользуемся формулой в ячейке G1: =СУММ(A1:C1)-МАКС(A1:C1)-МИН(A1:C1)
Чтобы определить полупериметр, воспользуемся формулой в ячейке H1: =СУММ(A1:C1)/2
Неравенство треугольника проверим формулой =ЕСЛИ(E1<F1+G1;1;0)
Добавим в эту формулу вместо единицы формулу Герона: =ЕСЛИ(E1<F1+G1;КОРЕНЬ(H1*(H1-E1)*(H1-F1)*(H1-G1));0)
Максимальную площадь найдём поиском максимума в столбце площадей: =МАКС(I:I)
Наибольшая площадь: 3942,653. Округлив до целого, получим окончательный ответ: 3943.
Ответ: 3943.
Рекомендуемые курсы подготовки
- Узнаешь всё про кодирование: что это такое и как происходит
- Познакомишься с Условием Фано: как оно примняется и почему важно
- Научишься считать колиечтсво информации и сколько под неё нужно выделить памяти
на бесплатном курсе Турбо ЕГЭ
